home *** CD-ROM | disk | FTP | other *** search
/ TPUG - Toronto PET Users Group / TPUG Users Group CD / TPUG Users Group CD.iso / C64 / T-TPUG Old Monthly Disks / (c)t3.d64 / disk menu 64.c (.txt) < prev    next >
Commodore BASIC  |  2007-02-04  |  1KB  |  50 lines
  1. 100 REM VIC/64 DISK MENU
  2. 110 POKE 53281,1
  3. 120 CLR
  4. 130 PRINT"[147]READING DISK DIRECTORY"
  5. 140 DIMP$(100)
  6. 150 REM DIRECTORY
  7. 160 IFST=0THENX=X+1:GOTO180
  8. 170 OPEN1,8,0,"$"
  9. 180 REM LOAD ARRAY P$
  10. 190 GET#1,B$:IFST<>0THEN270
  11. 200 IFB$<>CHR$(34)THEN190
  12. 210 P$=""
  13. 220 GET#1,B$:IFB$<>CHR$(34)THENP$=P$+B$:GOTO220
  14. 230 GET#1,B$:IFB$=CHR$(32)THEN230
  15. 240 P$(X)=P$:PRINTX;"[145]"
  16. 250 GET#1,B$:IFB$<>""THEN250
  17. 260 IFST=0THENX=X+1:GOTO180
  18. 270 CLOSE1
  19. 280 REM  DISPLAY MENU
  20. 290 N=10
  21. 300 PRINT"[147]64 DISC MENU"
  22. 310 PRINT"FOR ";P$(0);"":PRINT
  23. 320 IFN<10THENN=10
  24. 330 IFN>100THENN=100
  25. 340 FORJ=(N-9)TON:PRINTJ;"- ";P$(J):NEXTJ
  26. 350 PRINT:PRINT"PRESS[157][157][157][157][157]N FOR NEXT SCREEN"
  27. 360 PRINT"L FOR LAST SCREEN"
  28. 370 PRINT"E TO EXIT TO BASIC"
  29. 380 PRINT"[156]S TO LOAD ONLY"
  30. 390 PRINT"R TO LOAD AND RUN"
  31. 400 Z$="":GETZ$:IFZ$=""THEN400
  32. 410 IFZ$="N"THENN=N+10:GOTO300
  33. 420 IFZ$="L"THENN=N-10:GOTO300
  34. 430 IFZ$="E"THENPRINT"MENU STILL PRESENT":END
  35. 440 IFZ$="S"THENGOSUB470:GOTO570
  36. 450 IFZ$="R"THENGOSUB470:GOTO540
  37. 460 GOTO400
  38. 470 REM SELECT AND            PRINT LOAD
  39. 480 PRINT"PROGRAM#";
  40. 490 INPUTS:PRINT""
  41. 500 IFS<1ORS>XTHEN480
  42. 510 IFLEN(P$(S))>12THENP$(S)=LEFT$(P$(S),12)+"*"
  43. 520 PRINT"LOAD"+CHR$(34)+P$(S)+CHR$(34)+",8[145][145][145]"
  44. 530 RETURN
  45. 540 REM LOAD AND RUN
  46. 550 POKE631,13:POKE632,82:POKE633,85:POKE634,78:POKE635,13:POKE198,5
  47. 560 END
  48. 570 REM LOAD ONLY
  49. 580 POKE631,13:POKE198,1
  50.